ローカルルータ: sakuracloud_local_router

Example Usage

resource "sakuracloud_local_router" "foobar" {
  name        = "example"
  description = "descriptio"
  tags        = ["tag1", "tag2"]

  switch {
    code     = sakuracloud_switch.foobar.id
    category = "cloud"
    zone_id  = "is1a"
  }

  network_interface {
    vip          = "192.168.11.1"
    ip_addresses = ["192.168.11.11", "192.168.11.12"]
    netmask      = 24
    vrid         = 101
  }

  static_route {
    prefix   = "10.0.0.0/24"
    next_hop = "192.168.11.2"
  }
  static_route {
    prefix   = "172.16.0.0/16"
    next_hop = "192.168.11.3"
  }

  peer {
    peer_id     = data.sakuracloud_local_router.peer.id
    secret_key  = data.sakuracloud_local_router.peer.secret_keys[0]
    description = "description"
  }
}

resource "sakuracloud_switch" "foobar" {
  name = "example"
}

data "sakuracloud_local_router" "peer" {
  filter {
    names = ["peer"]
  }
}

Code Editor

Argument Reference

network_interfaceブロック
  • ip_addresses - (Required) IPアドレスのリスト
  • netmask - (Required) サブネットマスク長 / 8-29の範囲で指定
  • vip - (Required) 仮想IPアドレス
  • vrid - (Required) VRID
peerブロック
  • peer_id - (Required) ピアのリソースID
  • secret_key - (Required) ピアのシークレットキー
  • description - (Optional) 説明 / 1-512文字で指定
  • enabled - (Optional) 有効フラグ
static_routeブロック
  • next_hop - (Required) ネクストホップのIPアドレス
  • prefix - (Required) プレフィックスCIDRブロック
switchブロック
  • category - (Optional) 接続先スイッチのサービス名 (例: cloud, vps)
  • code - (Required) 接続するスイッチのリソースID
  • zone_id - (Required) 接続先スイッチの属するゾーン(例: is1a, tk1a)

Note

現在はさくらのクラウドのスイッチにのみ対応。
VPS/専用サーバは未対応です。

Common Arguments

  • description - (Optional) 説明 / 1-512文字で指定
  • icon_id - (Optional) アイコンID
  • tags - (Optional) タグ

Timeouts

timeoutsブロックでカスタムタイムアウトが設定可能です。

  • create - 作成 (デフォルト: 20分)
  • update - 更新 (デフォルト: 20分)
  • delete - 削除 (デフォルト: 20分)

Attribute Reference

  • id - ID
  • secret_keys - シークレットキーのリスト。他のローカルルータからピアリングする際に利用する